How the Script works

Beside the standard GSE blocks there are three additional functions being implemented in custom VBScript code.

This three functions are derived from the specification of the application:

• Check the PIN against the database
• Playback the recorded message
• Save the recorded message with a specific filename in the given folder and update the database

The function "ValidPin()"

This function will be called using the Evaluate block Valid PIN ?:

The function gets the entered PIN as parameter. The connect string to the database DB_DSN is defined in the first statement of the custom VBScript code ' Data Source Name
Const DB_DSN = "valentines" and can be altered there if necessary.

Function ValidPin ( sPin )


  Dim bReturn
  bReturn = false


  ' open connection to database
  Dim db
  Set db = CreateObject("ADODB.Connection")
  db.Open DB_DSN


  ' open recordset
  Dim sSQL
  Dim rs
  sSQL = "select * from users where pin = '" _
    & sPin & "'"


  Set rs = CreateObject("ADODB.Recordset")
  rs.Open sSQL, db, adOpenDynamic, _
    adLockOptimistic, adCmdText
  bReturn = not rs.EOF


  rs.Close
  Set rs = Nothing


  db.Close
  Set db = Nothing


  ValidPin = bReturn


End Function

The function "PlayLastMessage ()"

This function will be called using the Set Variable block Play Message. Please note that we use this block just for calling the function. We are not interested in its return value.

The GSE currently do not have a simple to get the name of the the last recorded maeesage, but we can use its scripting interface to do it:

Function PlayLastMessage ()


  Dim retVal
  Dim sFileName


  ' get name of last recorded file
  sFileName = PBXCall.LastRecordedMessage
  ' play last recorded file
  retVal = PBXCall.PlayMessage(sFileName)


  PlayLastMessage = True


End Function

The function "SaveMessage()"

This function does the following:

• The recorded message will be stored in the defined SAVE_DIR directory with a name PIN.WAV, where PIN is the PIN of the current user.
• The complete filename including the path will be stored in the user's record in the database.

Function SaveMessage( sPin )


  Dim sFileName, sNewFileName


  ' get name of last recorded file
  sFileName = PBXCall.LastRecordedMessage
  ' cal new file name
  sNewFileName = SAVE_DIR & sPin & ".wav"
  ' create FileSystemObject
  Dim fso
  Set fso = CreateObject("Scripting.FileSystemObject")
  fso.CopyFile sFileName, sNewFileName
  Set fso = Nothing


  ' open connection to database
  Dim db
  Set db = CreateObject("ADODB.Connection")
  db.Open DB_DSN


  ' update record
  Dim sSQL
  sSQL = "update users set message = '" & _
    sNewFileName & "' where pin = '" & _
    sPin & "'"
  db.Execute(sSQL)


  db.Close
  Set db = Nothing


  SaveMessage = True


End Function

Please note that the announcements within the ZIP file are not the ones being used during the valentines camgain, but instead are just some test announcements.

Further informations about the valentines campaign

The campaign was of course more then just this GSE script. On the following webpages one was able to login to it:

• www.langhout.nl
• www.gekkie.nl
• www.valentijnsboodschap.nl

The Webpages where created by the company Web Power (www.webpower.nl) who where also responsible to sent all the valentines emails.